Ticket #142: db.adb

with Ada.Unchecked_Deallocation;

with SQL.Databases;
with SQL.Queries;
with Matreshka.Internals.SQL_Drivers.SQLite3.Factory;

with League.Strings;
with League.Holders.Integers;
with League.Text_Codecs;

package body DB is

   type Database_Access is access all SQL.Databases.SQL_Database;

   procedure Free is new
     Ada.Unchecked_Deallocation (SQL.Databases.SQL_Database, Database_Access);

   Connect : Database_Access;

   ASCII_Codec : constant League.Text_Codecs.Text_Codec :=
     League.Text_Codecs.Codec
       (League.Strings.To_Universal_String ("ISO-8859-1"));

   function "+"
     (Item : Wide_Wide_String) return League.Strings.Universal_String
      renames League.Strings.To_Universal_String;

   ------------------
   -- Add_Currency --
   ------------------

   procedure Add_Currency
     (Id      : Integer;
      Ratio   : Integer;
      Version : Integer)
   is
      Query : aliased SQL.Queries.SQL_Query := Connect.Query
        (+("INSERT INTO CURRENCIES (ID, VERSION, RATIO) "
         & "VALUES (:ID, :VERSION, :RATIO)"));

      use League.Holders;
   begin
      Query.Bind_Value (+":ID", Integers.To_Holder (Id));

      Query.Bind_Value
        (+":VERSION", Integers.To_Holder (Version));

      Query.Bind_Value
        (+":RATIO", Integers.To_Holder (Ratio));

      Query.Execute;
      Connect.Commit;
   end Add_Currency;

   -----------
   -- Close --
   -----------

   procedure Close is
   begin
      if Connect /= null then
         Connect.Close;
         Free (Connect);
      end if;
   end Close;

   ---------------------
   -- Delete_Currency --
   ---------------------

   procedure Delete_Currency (Id : Integer)
   is
      Query : aliased SQL.Queries.SQL_Query := Connect.Query
        (+"DELETE FROM CURRENCIES WHERE ID=:ID");

      use League.Holders.Integers;
   begin
      Query.Bind_Value (+":ID", To_Holder (Id));

      Query.Execute;
      Connect.Commit;
   end Delete_Currency;

   ----------
   -- Open --
   ----------

   procedure Open is
      DB_Driver : constant League.Strings.Universal_String :=
        League.Strings.To_Universal_String ("SQLITE3");
      DB_Options : constant League.Strings.Universal_String :=
        League.Strings.To_Universal_String ("local.db");
   begin
      Connect := new SQL.Databases.SQL_Database'
        (SQL.Databases.Create (DB_Driver, DB_Options));

      Connect.Open;

      declare
         Query : SQL.Queries.SQL_Query := Connect.Query
           (+("CREATE TABLE IF NOT EXISTS CURRENCIES "
            & "(ID NOT NULL, VERSION NOT NULL, RATIO NOT NULL)"));
      begin
         Query.Execute;
      end;

      Connect.Commit;
   end Open;

   ---------------------
   -- Update_Currency --
   ---------------------

   procedure Update_Currency
     (Id      : Integer;
      Ratio   : Integer;
      Version : Integer)
   is
      Query : aliased SQL.Queries.SQL_Query := Connect.Query
        (+("UPDATE CURRENCIES SET VERSION=:VERSION, "
         & "RATIO=:RATIO WHERE ID=:ID"));

      use League.Holders.Integers;
   begin
      Query.Bind_Value (+":ID", To_Holder (Id));
      Query.Bind_Value (+":VERSION", To_Holder (Version));
      Query.Bind_Value (+":RATIO", To_Holder (Ratio));
      Query.Execute;

      Connect.Commit;
   end Update_Currency;

end DB;